Дневник игрока в самую "эзотерическую" игру... Рулетку.

procedure TfrmMain.Generate;
var
  i,n: Int64;
  i01,i02,i03: Integer;
  K,T: array of Integer;

  procedure PrintInfo;
  var
    j0: Integer;
    str: String;
  begin
    str:=Format(
      '========================================================================='+sLineBreak+
      'Исходные данные:'+sLineBreak+
      '-> Количество спинов невыпадения числа: %d'+sLineBreak+
      '-> Количество последующих наблюдений:   %d'+sLineBreak+
      '-> Параметры ГПСЧ:'+sLineBreak+
      '---> Вес Delphi-функции Random: %d'+sLineBreak+
      '---> Вес Вихря Мерсенна:        %d'+sLineBreak+
      '========================================================================='+sLineBreak+
      'Всего проведено: %d испытаний'+sLineBreak+
      'Среди них невыпадение одного номера за %d спинов встретилось %d раз'+sLineBreak+
      '========================================================================='+sLineBreak+
      'Отчёт о частоте выпадения этого номера на следующих %d спинах:'+sLineBreak,
      [FN,FK,FRng.DelphiRandom,FRng.MersennVihr,i,FN,n,FK]);
    for j0:=0 to Length(K)-1 do
      str:=str+Format(
        '%d раз: %d испытаний',[j0,K[j0]]
      )+sLineBreak;
    str:=str+Format(
      '========================================================================='+sLineBreak+
      'Отчёт о моменте первого выпадения искомого числа на следующих %d спинах:'+sLineBreak,
      [FK]);
    for j0:=1 to Length(T)-1 do
      str:=str+Format(
        '%d спин: %d испытаний',[j0,T[j0]]
      )+sLineBreak;
    str:=str+Format(
        'Не выпало ни разу: %d испытаний',[T[0]]);

    memInfo.Text:=str;
  end;

var
  wheel: Int64; //Здесь в виде битового флага храним информацию о невыпавших номерах
  num: Int64;
  rnd, MyNumb, foundCnt: Integer;
  found: Boolean;
begin

  i:=0;
  n:=0;
  i01:=0;
  SetLength(K,FK+1);
  SetLength(T,FK+1);

  while true do begin
    Application.ProcessMessages; //Это, чтобы программа не висела, пока расчёт идёт
    wheel:=$1FFFFFFFFF;          //Это 64-битное число записываем в каждый бит, начиная с младшего,
                                 //37 единичек. Каждая единичка (бит) указывает на то, что это
                                 //число ещё не выпадало. Когда число выпадет, мы заменим единичку на 0
    inc(i);      //Увеличиваем счётчик общего количества испытаний
    inc(i01);    //Этот счётчик используется для того, чтобы каждый 1 млн. испытаний
                 //Обновлять информацию в отчёте


    //Генерируем первые FN чисел (FN-это параметр, который мы задаём. По умолчанию FN=500)
    for i02:=1 to FN do begin
      num:=1;
      rnd:=GetRnd;                       //Здесь мы генерируем случайое число от 0 до 36
      wheel:=wheel and (not (num shl rnd));  //В этой строке мы сбрасываем бит, соответствующий
                                             //выпавшему случайному числу. Т.е. заменяем единичку на
                                             //нолик (см. выше)
      if wheel=0 then break;                 //Если все биты сброшен, т.е. все числа от 0 до 36
                                             //уже выпали, то прекращаем генерацию, т.к. эта последовательность
                                             //нам не интересна
    end;

    if wheel<>0 then begin //Если есть невыпашие номера, то обрабатываем их
      inc(n);  //Увеличиваем счётчик найденных ситуаций, когда наш номер не выпал заданное число раз

      //Берём первый попавшийся невыпавший номер (их может быть несколько)
      MyNumb:=-1;
      for i02:=0 to 36 do begin
        num:=1;
        num:=num shl i02;
        if (wheel and num)<>0 then begin
          MyNumb:=i02;  //Здесь мы нашли номер, который у нас не выпадал 500 раз
          break;
        end;
      end;

      if MyNumb<>-1 then begin
        //Генерируем оставшиеся FK (задаётся пользователем, по умолчанию =35) номеров и записываем статистику
        found:=false;                //Наш искомый номер ещё не найден...
        foundCnt:=0;                 //... и не выпадал пока ни разу
        for i03:=1 to FK do begin
          rnd:=GetRnd;           //Генерируем случайное число
          if rnd=MyNumb then begin   //Если это наш искомый номер ...
            if not found then begin
              inc(T[i03]);           //...то записываем на каком шаге он выпал в первый раз ...
              found:=true;           //...и запоминаем, что первое выпадение уже было...
            end;
            inc(foundCnt);           //Увеличиваем счётчик количества выпадений искомого номера
          end;
        end;
        if not found then inc(T[0]); //Если номер так и не удалось найти, то фиксируем это
        inc(K[foundCnt]);            //Записываем в массив для отчёта, сколько раз выпал наш номер
      end;

    end;

    if i01=1000000 then begin  //Обновляем отчёт после миллиона испытаний
      i01:=0;
      PrintInfo;
    end;
    if FNeedStop then begin   //Если пользователь нажал СТОП, то обновляем отчёт и выходим из цикла
      PrintInfo;
      break;
    end;

  end;
  SetLength(K,0);
  SetLength(T,0);
end;